feat(*): recreate library as scoped package

meta/mm_getusers.sas

@@ -0,0 +1,70 @@
+/**
+  @file mm_getusers.sas
+  @brief Creates a table containing a list of all users
+  @details Only shows a limited number of attributes as some sites will have a
+  LOT of users.
+
+  Usage:
+
+    %mm_getusers()
+
+  @param outds the dataset to create that contains the list of libraries
+
+  @returns outds  dataset containing all users, with the following columns:
+    - uri
+    - name
+
+  @warning The following filenames are created and then de-assigned:
+
+      filename sxlemap clear;
+      filename response clear;
+      libname _XML_ clear;
+
+  @version 9.3
+  @author Allan Bowe
+
+**/
+
+%macro mm_getusers(
+    outds=work.mm_getusers
+)/*/STORE SOURCE*/;
+
+filename response temp;
+proc metadata in= '<GetMetadataObjects>
+ <Reposid>$METAREPOSITORY</Reposid>
+ <Type>Person</Type>
+ <NS>SAS</NS>
+ <Flags>0</Flags>
+ <Options>
+ <Templates>
+ <Person Name=""/>
+ </Templates>
+ </Options>
+ </GetMetadataObjects>'
+  out=response;
+run;
+
+filename sxlemap temp;
+data _null_;
+  file sxlemap;
+  put '<SXLEMAP version="1.2" name="SASObjects"><TABLE name="SASObjects">';
+  put "<TABLE-PATH syntax='XPath'>/GetMetadataObjects/Objects/Person</TABLE-PATH>";
+  put '<COLUMN name="uri">';
+  put "<PATH syntax='XPath'>/GetMetadataObjects/Objects/Person/@Id</PATH>";
+  put "<TYPE>character</TYPE><DATATYPE>string</DATATYPE><LENGTH>32</LENGTH>";
+  put '</COLUMN><COLUMN name="name">';
+  put "<PATH syntax='XPath'>/GetMetadataObjects/Objects/Person/@Name</PATH>";
+  put "<TYPE>character</TYPE><DATATYPE>string</DATATYPE><LENGTH>256</LENGTH>";
+  put '</COLUMN></TABLE></SXLEMAP>';
+run;
+libname _XML_ xml xmlfileref=response xmlmap=sxlemap;
+
+proc sort data= _XML_.SASObjects out=&outds;
+  by name;
+run;
+
+filename sxlemap clear;
+filename response clear;
+libname _XML_ clear;
+
+%mend;