chore: moving files to tidy up docs

tests/viyaonly/mfv_existfile.test.sas

@@ -0,0 +1,34 @@
+/**
+  @file
+  @brief Testing mfv_existfile macro function
+
+  <h4> SAS Macros </h4>
+  @li mf_uid.sas
+  @li mfv_existfile.sas
+  @li mp_assert.sas
+  @li mv_createfile.sas
+
+**/
+
+options mprint sgen;
+
+%let file=%mf_uid();
+
+/* create a folder */
+filename somefile temp;
+data _null_;
+  file somefile;
+  put 'hello testings';
+run;
+%mv_createfile(path=&mcTestAppLoc/temp, name=&file..txt,inref=somefile)
+
+
+%mp_assert(
+  iftrue=(%mfv_existfile(&mcTestAppLoc/temp/&file..txt)=1),
+  desc=Check if created file exists
+)
+
+%mp_assert(
+  iftrue=(%mfv_existfile(&mcTestAppLoc/temp/%mf_uid().txt)=0),
+  desc=Check if non created file does not exist
+)

tests/viyaonly/mfv_existfolder.test.sas

@@ -0,0 +1,29 @@
+/**
+  @file
+  @brief Testing mfv_existfolder macro function
+
+  <h4> SAS Macros </h4>
+  @li mf_uid.sas
+  @li mfv_existfolder.sas
+  @li mp_assert.sas
+  @li mv_createfolder.sas
+
+**/
+
+options mprint sgen;
+
+%let folder=%mf_uid();
+
+/* create a folder */
+%mv_createfolder(path=&mcTestAppLoc/temp/&folder)
+
+
+%mp_assert(
+  iftrue=(%mfv_existfolder(&mcTestAppLoc/temp/&folder)=1),
+  desc=Check if created folder exists
+)
+
+%mp_assert(
+  iftrue=(%mfv_existfolder(&mcTestAppLoc/temp/&folder/%mf_uid()/noway)=0),
+  desc=Check if non created folder does not exist
+)

tests/viyaonly/mv_createfile.test.sas

@@ -0,0 +1,42 @@
+/**
+  @file
+  @brief Testing mv_createfile macro
+
+  <h4> SAS Macros </h4>
+  @li mf_uid.sas
+  @li mfv_existfile.sas
+  @li mp_assert.sas
+  @li mv_createfile.sas
+
+
+**/
+
+options mprint;
+
+%let file=%mf_uid();
+
+%put TEST 1 - basic file upload ;
+filename somefile temp;
+data _null_;
+  file somefile;
+  put 'hello testings';
+run;
+%mv_createfile(path=&mcTestAppLoc/temp, name=&file..txt,inref=somefile)
+
+%mp_assert(
+  iftrue=(%mfv_existfile(&mcTestAppLoc/temp/&file..txt)=1),
+  desc=Check if created file exists
+)
+
+%put TEST 2 - dataset upload ;
+data temp;
+x=1;
+run;
+filename ds "%sysfunc(pathname(work))/temp.sas7bdat";
+
+%mv_createfile(path=&mcTestAppLoc/temp, name=&file..sas7bdat,inref=ds)
+
+%mp_assert(
+  iftrue=(%mfv_existfile(&mcTestAppLoc/temp/&file..sas7bdat)=1),
+  desc=Check if created dataset exists
+)

tests/viyaonly/mv_createfolder.test.sas

@@ -0,0 +1,32 @@
+/**
+  @file
+  @brief Testing mv_createfolder macro
+
+  <h4> SAS Macros </h4>
+  @li mf_uid.sas
+  @li mp_assert.sas
+  @li mv_createfolder.sas
+  @li mv_deleteviyafolder.sas
+  @li mv_getfoldermembers.sas
+
+**/
+
+
+%let folder=%mf_uid();
+
+/* create a folder */
+%mv_createfolder(path=&mcTestAppLoc/temp/&folder/&folder)
+
+%mv_getfoldermembers(root=&mcTestAppLoc/temp/&folder, outds=work.folders)
+
+%let test=0;
+data _null_;
+  set work.folders;
+  putlog (_all_)(=);
+  if name="&folder" then call symputx('test',1);
+run;
+
+%mp_assert(
+  iftrue=(&test=1),
+  desc=Check if temp folder can be successfully created
+)

tests/viyaonly/mv_createwebservice.test.sas

@@ -0,0 +1,45 @@
+/**
+  @file
+  @brief Testing mv_createwebservice macro
+
+  <h4> SAS Macros </h4>
+  @li mv_createwebservice.sas
+  @li mv_getjobcode.sas
+
+**/
+
+/**
+  * Test Case 1
+  * Send special char in a service
+  */
+
+filename testref temp;
+data _null_;
+  file testref;
+  put '01'x;
+run;
+%put TEST1: creating web service;
+%mv_createwebservice(
+  path=&mcTestAppLoc/temp/macros,
+  name=mv_createwebservice,
+  code=testref
+)
+%put TEST1: fetching web service code;
+%mv_getjobcode(
+  path=&mcTestAppLoc/temp/macros,
+  name=mv_createwebservice,
+  outref=compare
+)
+%put TEST1: checking web service code;
+data work.test_results;
+  length test_description $256 test_result $4 test_comments $256;
+  infile compare end=eof;
+  input;
+  if eof then do;
+    if _infile_='01'x then test_result='PASS';
+    else test_result='FAIL';
+    test_description="Creating web service with invisible character";
+    output;
+    stop;
+  end;
+run;

tests/viyaonly/mv_getjobcode.test.sas

@@ -0,0 +1,49 @@
+/**
+  @file
+  @brief Testing mv_getjobcode macro
+
+  <h4> SAS Macros </h4>
+  @li mp_assert.sas
+  @li mv_createjob.sas
+  @li mv_getjobcode.sas
+
+**/
+
+/**
+  * Test Case 1
+  */
+
+/* write some code to a job */
+%let incode=%str(data test; set sashelp.class;run;);
+filename testref temp;
+data _null_;
+  file testref;
+  put "&incode";
+run;
+%mv_createjob(
+  code=testref,
+  path=&mcTestAppLoc/services/temp,
+  name=some_job
+)
+
+/* now get the code back */
+%mv_getjobcode(
+  path=&mcTestAppLoc/services/temp,
+  name=some_job,
+  outref=mycode
+)
+
+%let diditexist=NO;
+data work.test1;
+  infile mycode;
+  input;
+  putlog _infile_;
+  line=_infile_;
+  check=symget('incode');
+  if _infile_=symget('incode') then call symputx('diditexist','YES');
+run;
+
+%mp_assert(
+  iftrue=(&diditexist=NO),
+  desc=Check if the code that was sent was successfully retrieved
+)

tests/viyaonly/mv_getjoblog.test.sas

@@ -0,0 +1,70 @@
+/**
+  @file
+  @brief Testing mv_createwebservice macro
+
+  <h4> SAS Macros </h4>
+  @li mp_assert.sas
+  @li mv_createjob.sas
+  @li mv_jobexecute.sas
+  @li mv_jobwaitfor.sas
+  @li mv_getjoblog.sas
+
+**/
+
+/**
+  * Test Case 1
+  */
+
+/* create a service */
+filename testref temp;
+data _null_;
+  file testref;
+  put 'data;run;';
+  put 'endsas;';
+run;
+%mv_createjob(
+  path=&mcTestAppLoc/jobs/temp,
+  code=testref,
+  name=testjob
+)
+
+%* Execute it;
+%mv_jobexecute(
+  path=&mcTestAppLoc/jobs/temp,
+  name=testjob,
+  outds=work.info
+)
+
+%* Wait for it to finish;
+data work.info;
+  set work.info;
+  where method='GET' and rel='state';
+run;
+%mv_jobwaitfor(ALL,inds=work.info,outds=work.jobstates)
+
+%* and grab the uri;
+data _null_;
+  set work.jobstates;
+  call symputx('uri',uri);
+run;
+
+%* Finally, fetch the log;
+%mv_getjoblog(uri=%str(&uri),outref=mylog)
+
+
+data _null_;
+  infile mylog end=eof;
+  input;
+  putlog _infile_;
+  retain found 0;
+  if index(_infile_,'endsas;') then do;
+    found=1;
+    call symputx('found',found);
+  end;
+  else if eof and found ne 1 then call symputx('found',0);
+run;
+
+%mp_assert(
+  iftrue=(%str(&found)=1),
+  desc=Check if the log was still fetched even though endsas was submitted
+)

tests/viyaonly/mv_getjobresult.test.sas

@@ -0,0 +1,76 @@
+/**
+  @file
+  @brief Testing mv_createwebservice macro
+
+  <h4> SAS Macros </h4>
+  @li mp_assertdsobs.sas
+  @li mv_createwebservice.sas
+  @li mv_getjobresult.sas
+  @li mv_jobflow.sas
+
+**/
+
+options mprint notes;
+
+/**
+  * Test Case 1
+  */
+
+/* create a service */
+filename testref temp;
+data _null_;
+  file testref;
+  put 'data test; set sashelp.class;run;';
+  put '%webout(OPEN)';
+  put '%webout(OBJ,test)';
+  put '%webout(CLOSE)';
+run;
+%mv_createwebservice(
+  path=&mcTestAppLoc/services/temp,
+  code=testref,
+  name=testsvc
+)
+
+/* trigger and wait for it to finish */
+data work.inputjobs;
+  _program="&mcTestAppLoc/services/temp/testsvc";
+run;
+%mv_jobflow(inds=work.inputjobs
+  ,maxconcurrency=4
+  ,outds=work.results
+  ,outref=myjoblog
+)
+/* stream the log */
+data _null_;
+  infile myjoblog;
+  input;
+  put _infile_;
+run;
+
+/* fetch the uri */
+data _null_;
+  set work.results;
+  call symputx('uri',uri);
+  put (_all_)(=);
+run;
+
+/* now get the results */
+%mv_getjobresult(uri=&uri
+  ,result=WEBOUT_JSON
+  ,outref=myweb
+  ,outlib=myweblib
+)
+data _null_;
+  infile myweb;
+  input;
+  putlog _infile_;
+run;
+data work.out;
+  set myweblib.test;
+  put (_all_)(=);
+run;
+%mp_assertdsobs(work.out,
+  desc=Test1 - 19 obs from sashelp.class in service result,
+  test=EQUALS 19,
+  outds=work.test_results
+)

tests/viyaonly/mv_jobflow.test.1.sas

@@ -0,0 +1,78 @@
+/**
+
+  @file
+  @brief Testing mv_jobflow macro
+  @details One of the remote jobs aborts with syscc>0 - test to
+  make sure this comes back to the calling session
+​
+  <h4> SAS Macros </h4>
+  @li mp_assert.sas
+  @li mv_createjob.sas
+  @li mv_jobflow.sas
+
+**/
+
+/**
+  * Test Case 1
+  */
+
+filename testprog temp;
+data _null_;
+  file testprog;
+  put '%put this is job: &_program;'
+  /   '%put this was run in flow &flow_id;'
+  /   'data ;'
+  /   '  rval=rand("uniform");'
+  /   '  rand=rval*&macrovar1;'
+  /   '  do x=1 to rand;'
+  /   '    y=rand*&macrovar2;'
+  /   '    if (rval>0.50) then abort;'
+  /   '    else output;'
+  /   '  end;'
+  /   'run;'
+  ;
+run;
+
+%mv_createjob(path=/Public/temp,name=demo1,code=testprog)
+%mv_createjob(path=/Public/temp,name=demo2,code=testprog)
+
+data work.inputjobs;
+  _contextName='SAS Job Execution compute context';
+  do flow_id=1 to 2;
+    do i=1 to 4;
+      _program='/Public/temp/demo1';
+      macrovar1=10*i;
+      macrovar2=4*i;
+      output;
+      i+1;
+      _program='/Public/temp/demo2';
+      macrovar1=40*i;
+      macrovar2=44*i;
+      output;
+    end;
+  end;
+run;
+
+* Trigger the flow ;
+
+%put NOTE: &=syscc;
+
+%mv_jobflow(inds=work.inputjobs
+  ,maxconcurrency=2
+  ,outds=work.results
+  ,outref=myjoblog
+  ,raise_err=1
+  ,mdebug=1
+)
+
+%put NOTE: &=syscc;
+
+data _null_;
+  infile myjoblog;
+  input; put _infile_;
+run;
+
+%mp_assert(
+  iftrue=(&syscc ne 0),
+  desc=Check that non zero return code is returned if called job fails
+)

tests/viyaonly/mv_jobflow.test.2.sas

@@ -0,0 +1,74 @@
+/**
+  @file
+  @brief Testing mv_jobflow macro
+  @details All jobs complete successfully with syscc = 0 - test to
+  make sure this comes back to the calling session
+​
+  <h4> SAS Macros </h4>
+  @li mp_assert.sas
+  @li mv_createjob.sas
+  @li mv_jobflow.sas
+**/
+
+/**
+  * Test Case 1
+  */
+filename testprog temp;
+data _null_;
+  file testprog;
+  put '%put this is job: &_program;'
+  /   '%put this was run in flow &flow_id;'
+  /   'data ;'
+  /   '  rval=rand("uniform");'
+  /   '  rand=rval*&macrovar1;'
+  /   '  do x=1 to rand;'
+  /   '    y=rand*&macrovar2;'
+  /   '    output;'
+  /   '  end;'
+  /   'run;'
+  ;
+run;
+
+%mv_createjob(path=/Public/temp,name=demo1,code=testprog)
+%mv_createjob(path=/Public/temp,name=demo2,code=testprog)
+
+data work.inputjobs;
+  _contextName='SAS Job Execution compute context';
+  do flow_id=1 to 2;
+    do i=1 to 4;
+      _program='/Public/temp/demo1';
+      macrovar1=10*i;
+      macrovar2=4*i;
+      output;
+      i+1;
+      _program='/Public/temp/demo2';
+      macrovar1=40*i;
+      macrovar2=44*i;
+      output;
+    end;
+  end;
+run;
+
+* Trigger the flow ;
+
+%put NOTE: &=syscc;
+
+%mv_jobflow(inds=work.inputjobs
+  ,maxconcurrency=2
+  ,outds=work.results
+  ,outref=myjoblog
+  ,raise_err=1
+  ,mdebug=1
+)
+
+%put NOTE: &=syscc;
+
+data _null_;
+  infile myjoblog;
+  input; put _infile_;
+run;
+
+%mp_assert(
+  iftrue=(&syscc eq 0),
+  desc=Check that a zero return code is returned if no called job fails
+)

tests/viyaonly/mv_registerclient.test.1.sas

@@ -0,0 +1,36 @@
+/**
+
+  @file
+  @brief Testing mv_registerclient.sas macro
+  @details Tests for successful registration.  For this to work, the test
+  account must be an admin.
+​
+  <h4> SAS Macros </h4>
+  @li mf_getuniquename.sas
+  @li mp_assertcolvals.sas
+  @li mv_registerclient.sas
+
+**/
+
+/**
+  * Test Case 1
+  */
+
+%let id=%mf_getuniquename();
+%let sec=%mf_getuniquename();
+%mv_registerclient(client_id=&id,client_secret=&sec, outds=testds)
+
+data work.checkds;
+  id="&id";
+  sec="&sec";
+run;
+%mp_assertcolvals(work.testds.client_id,
+  checkvals=work.checkds.id,
+  desc=Checking client id was created
+  test=ALLVALS
+)
+%mp_assertcolvals(work.testds.client_secret,
+  checkvals=work.checkds.sec,
+  desc=Checking client secret was created
+  test=ALLVALS
+)

tests/viyaonly/mv_registerclient.test.2.sas

@@ -0,0 +1,43 @@
+/**
+
+  @file
+  @brief Testing mv_registerclient.sas macro
+  @details Tests for unsuccessful registration.  To do this, overrides are
+  applied for the mf_loc.sas and mp_abort.sas macros.
+​
+  <h4> SAS Macros </h4>
+  @li mp_assert.sas
+  @li mv_registerclient.sas
+
+**/
+
+/**
+  * Test Case
+  */
+
+%macro mf_loc(param);
+  /does/not/exist
+%mend mf_loc;
+
+%macro mp_abort(iftrue=,mac=mp_abort.sas, type=, msg=);
+  %if not(%eval(%unquote(&iftrue))) %then %return;
+  %put %substr(&msg,1,16);
+  %mp_assert(
+    iftrue=("%substr(&msg,1,16)"="Unable to access"),
+    desc=Check that abort happens when consul token is unavailable
+  )
+  %webout(OPEN)
+  %webout(OBJ, TEST_RESULTS)
+  %webout(CLOSE)
+  %let syscc=0;
+  data _null_;
+    abort cancel nolist;
+  run;
+%mend mp_abort;
+
+%mv_registerclient( outds=testds)
+
+%mp_assert(
+  iftrue=(0=1),
+  desc=Check that abort happens when consul token is unavailable
+)

tests/viyaonly/mv_webout.test.sas

@@ -0,0 +1,41 @@
+/**
+  @file
+  @brief Testing mm_webout macro
+
+  <h4> SAS Macros </h4>
+  @li mf_getuniquefileref.sas
+  @li mv_webout.sas
+  @li mp_assert.sas
+
+**/
+
+
+%let fref=%mf_getuniquefileref();
+%global _metaperson;
+data some datasets;
+  x=1;
+run;
+%mv_webout(OPEN,fref=&fref,stream=N)
+%mv_webout(ARR,some,fref=&fref,stream=N)
+%mv_webout(OBJ,datasets,fref=&fref,stream=N)
+%mv_webout(CLOSE,fref=&fref,stream=N)
+
+data _null_;
+  infile &fref;
+  input;
+  putlog _infile_;
+run;
+
+libname test JSON (&fref);
+data root;
+  set test.root;
+  call symputx('checkval',sysvlong);
+run;
+data alldata;
+  set test.alldata;
+run;
+
+%mp_assert(
+  iftrue=(%str(&checkval)=%str(&sysvlong)),
+  desc=Check if the sysvlong value was created
+)