mirror of
https://github.com/sasjs/core.git
synced 2025-12-10 14:04:36 +00:00
87 lines
2.3 KiB
SAS
87 lines
2.3 KiB
SAS
/**
|
|
@file mv_getgroups.sas
|
|
@brief Creates a dataset with a list of viya groups
|
|
@details First, load the macros:
|
|
|
|
filename mc url
|
|
"https://raw.githubusercontent.com/sasjs/core/main/all.sas";
|
|
%inc mc;
|
|
|
|
Next, execute:
|
|
|
|
%mv_getgroups(outds=work.groups)
|
|
|
|
@param [in] access_token_var= (ACCESS_TOKEN)
|
|
The global macro variable to contain the access token
|
|
@param [in] grant_type= (sas_services)
|
|
valid values are "password" or "authorization_code" (unquoted).
|
|
@param [out] outds= (work.viyagroups)
|
|
The library.dataset to be created that contains the list of groups
|
|
|
|
|
|
@version VIYA V.03.04
|
|
@author Allan Bowe, source: https://github.com/sasjs/core
|
|
|
|
<h4> SAS Macros </h4>
|
|
@li mp_abort.sas
|
|
@li mf_getplatform.sas
|
|
@li mf_getuniquefileref.sas
|
|
@li mf_getuniquelibref.sas
|
|
|
|
**/
|
|
|
|
%macro mv_getgroups(access_token_var=ACCESS_TOKEN
|
|
,grant_type=sas_services
|
|
,outds=work.viyagroups
|
|
);
|
|
%local oauth_bearer base_uri fname1 libref1;
|
|
%if &grant_type=detect %then %do;
|
|
%if %symexist(&access_token_var) %then %let grant_type=authorization_code;
|
|
%else %let grant_type=sas_services;
|
|
%end;
|
|
%if &grant_type=sas_services %then %do;
|
|
%let oauth_bearer=oauth_bearer=sas_services;
|
|
%let &access_token_var=;
|
|
%end;
|
|
|
|
%mp_abort(iftrue=(&grant_type ne authorization_code and &grant_type ne password
|
|
and &grant_type ne sas_services
|
|
)
|
|
,mac=&sysmacroname
|
|
,msg=%str(Invalid value for grant_type: &grant_type)
|
|
)
|
|
|
|
options noquotelenmax;
|
|
/* location of rest apis */
|
|
%let base_uri=%mf_getplatform(VIYARESTAPI);
|
|
|
|
/* fetching folder details for provided path */
|
|
%let fname1=%mf_getuniquefileref();
|
|
%let libref1=%mf_getuniquelibref();
|
|
|
|
proc http method='GET' out=&fname1 &oauth_bearer
|
|
url="&base_uri/identities/groups?limit=10000";
|
|
headers
|
|
%if &grant_type=authorization_code %then %do;
|
|
"Authorization"="Bearer &&&access_token_var"
|
|
%end;
|
|
"Accept"="application/json";
|
|
run;
|
|
/*data _null_;infile &fname1;input;putlog _infile_;run;*/
|
|
%mp_abort(iftrue=(&SYS_PROCHTTP_STATUS_CODE ne 200)
|
|
,mac=&sysmacroname
|
|
,msg=%str(&SYS_PROCHTTP_STATUS_CODE &SYS_PROCHTTP_STATUS_PHRASE)
|
|
)
|
|
libname &libref1 JSON fileref=&fname1;
|
|
|
|
data &outds;
|
|
set &libref1..items;
|
|
run;
|
|
|
|
|
|
/* clear refs */
|
|
filename &fname1 clear;
|
|
libname &libref1 clear;
|
|
|
|
%mend mv_getgroups;
|